優先度スコアとは？
優先度スコアとは、「どの単語から優先的に学習すべきか」を数値で示す仕組みです。これにより、ユーザーは自分にとって今いちばん必要な単語から順に学習できるようになります。
💡 こんな人にこそ最適な機能です
-
「何から覚えるべきか迷う」
-
「復習をサボってしまった単語を見逃したくない」
-
「今の自分にとって効率的な順番で進めたい」
優先度スコアの計算方法
Vocabank Proでは、以下の項目をスコア化 → 正規化（0〜1）→ 加重平均で計算 → 最終スコア（0〜100点）という流れで算出しています。
習得モードの優先度スコア
| 項目 |
内容 |
ウェイト
（スコアへの影響度）
|
| 頻出度 |
高いほど高スコア |
50% |
| 習得度 |
低いほど高スコア |
30% |
| 難易度 |
低いほど高スコア |
20% |
🔎 頻出度は「🥇よく使う」〜「🔺あまり使わない」、習得度は「インプット中」〜「話せる」、難易度はA1〜C2で判定されています。
▶︎ 数式
((
(
(
if(prop("頻出度") == "🥇よく使う", 4,
if(prop("頻出度") == "🥈時々使う", 3,
if(prop("頻出度") == "🥉たまに使う", 2,
if(prop("頻出度") == "🔺あまり使わない", 1, 1)
)
)
) - 1
) / 3
) * 0.50
) + (
(
(
if(prop("習得度") == "インプット中", 4,
if(prop("習得度") == "インプット済", 3,
if(prop("習得度") == "瞬発クリア", 2,
if(prop("習得度") == "話せる", 1, 1)
)
)
) - 1
) / 3
) * 0.30
) + (
(
(
if(prop("難易度") == "A1(英検5~3級レベル)", 6,
if(prop("難易度") == "A2(英検準2級レベル)", 5,
if(prop("難易度") == "B1(英検2級レベル)", 4,
if(prop("難易度") == "B2(英検準1級レベル)", 3,
if(prop("難易度") == "C1(英検1級レベル)", 2,
if(prop("難易度") == "C2(英検1級超えレベル)", 1, 6)
)
)
)
)
) - 1
) / 5
) * 0.20
)) * 100
▶︎ 例
「remember」の場合
合計スコア：
(1.0×0.50) + (1.0×0.30) + (0.8×0.20) = 0.96
→ 0.96 × 100 = 96点
※習得度はインプット中だと仮定。
復習モードの優先度スコア
| 項目 |
内容 |
ウェイト
（スコアへの影響度）
|
| 頻出度 |
高いほど高スコア |
40% |
| 習得度 |
低いほど高スコア |
35% |
| 次回復習日 |
復習期限が過ぎているほど高い |
25% |
次回復習日は、今日より過去であればあるほど、スコアが高くなります。つまり、復習を忘れていた単語ほどスコアが自動で上がり、優先的に上に表示されるという仕組みです。ただし、最大30日分までが計算対象。それ以上過ぎていても、加点は同じです。
▶︎ 数式
((
(
(
if(prop("頻出度") == "🥇よく使う", 4,
if(prop("頻出度") == "🥈時々使う", 3,
if(prop("頻出度") == "🥉たまに使う", 2,
if(prop("頻出度") == "🔺あまり使わない", 1, 1)
)
)
) - 1
) / 3
) * 0.40
) + (
(
(
if(prop("習得度") == "インプット中", 4,
if(prop("習得度") == "インプット済", 3,
if(prop("習得度") == "瞬発クリア", 2,
if(prop("習得度") == "話せる", 1, 1)
)
)
) - 1
) / 3
) * 0.35
) + (
(
min(
max(
dateBetween(today(), prop("次回復習日"), "days"), 0
), 30
) / 30
) * 0.25
)) * 100
▶︎ 例
「remember」の場合
合計スコア：
(1.0×0.40) + (1.0×0.35) + (0.1×0.25) = 0.775
→ 0.775 × 100 = 77.5点
※習得度はインプット中、次回復習日は3日前と仮定。
ウェイトはお好みの値に変更可能です。
👉詳しいやり方はこちら
🔄 スコアは自動でリアルタイムに変わります
このスコアは、単語の習得状況や復習期日に応じて自動で再計算されます。
例えば、習得度ボタンを押すと、習得度が更新されるのでスコアも再計算されます。また、復習日を過ぎると、過ぎた分だけ優先度が高まるのでスコアも上昇していきます。
🚀 上から順に進めるだけで“最適”な学習ができる
Vocabank Proでは、習得モードでも復習モードでも、優先度スコア順に自動で単語が並ぶ設計です。そのため、「どこから手をつければいいか」と悩む必要はありません。ただ上から順に学習するだけで、最適な順番で語彙力が伸びていきます。
※習得モードの習得中の単語(インプット中~話せる)については、スムーズなフラッシュカード暗記を実現するために、優先度スコア順ではなく最終学習日順で表示されるように設定されています。
